home *** CD-ROM | disk | FTP | other *** search
/ Shareware Grab Bag / Shareware Grab Bag.iso / 010 / eamon1.arc / DUNGEON.BAS next >
Encoding:
BASIC Source File  |  1986-06-20  |  3.1 KB  |  74 lines
  1. 10 REM ///MINOTAUR'S LAIR STARTUP ROUTINE///
  2. 20 REM ///BY DONALD BROWN
  3. 30 REM ///
  4. 40 REM /// EAMON ADVENTURE
  5. 50 REM ///       #1
  6. 60 REM ///
  7. 70 REM /// MODIFIED FOR IBMPC 6/21/86
  8. 80 REM /// BY JOHN SKINNER
  9. 90 REM ///
  10. 100 KEY OFF : CLS : GOSUB 22029
  11. 110 SEX = 1 + (SEX$ = "F")
  12. 120 REL$ = "GIRLFRIEND" : PLNM$ = "LARCENOUS LIL" : S2$ = "SHE" : IF SEX = 0 THEN REL$ = "BOYFRIEND" : PLNM$ = "SLIPPERY SVEN" : S2$ = "HE"
  13. 130 PRINT : PRINT CNAME$;", YOU ARE IN BIG TROUBLE.":PRINT:PRINT:PRINT"YOU HAD ARRANGED TO MEET IN THE TOWN OF DUNDERHAVEN WITH YOUR ";REL$;",":PRINT
  14. 140 PRINT PLNM$;".  WHEN YOU ARRIVED, YOU LEARNED THAT ";PLNM$;" HAD COME"
  15. 150 PRINT:PRINT"INTO TOWN FLAT BROKE, AND HAD TRIED TO PICK UP SOME EASY CASH BY"
  16. 160 PRINT:PRINT"BURGLARIZING A NEARBY CASTLE.  ";S2$;" HASN'T BEEN SEEN SINCE."
  17. 170 PRINT:PRINT:PRINT"   MAKING YOUR OWN SUBTLE ENTRANCE INTO THE CASTLE, ALL SEEMED TO BE GOING WELL"
  18. 180 PRINT:PRINT"UNTIL SUDDENLY THE LIGHTS GO ON AND YOU SEE YOURSELF SURROUNDED BY BOWMEN AND A"
  19. 190 PRINT:PRINT"FAT, UGLY MAN ON A THRONE. HE SNEERS AT YOU AND SAYS 'WELL, BOYS, ANOTHER THIEF."
  20. 200 PRINT"I GUESS WE'LL SEND THE SCOUNDREL TO MEET THE FIRST.'  WITH THAT, HE PULLS"
  21. 210 PRINT:PRINT"A LEVER AND THE BOTTOM DROPS OUT OF THE FLOOR."
  22. 220 PRINT:PRINT"_______________________________________________________________________________";
  23. 230 FOR X=1 TO 20000 : NEXT X
  24. 240 LOCATE 24,1 : PRINT"______________________________                    _____________________________"
  25. 250 FOR X=1 TO 21:PRINT"                              |                  |":NEXT X
  26. 260 PRINT "                                      THUD!"
  27. 270 RUN "MAINPROG.BAS"
  28. 280 STOP
  29. 22029 A$="FRESHMEA.T"
  30. 22030 OPEN "I",#1,A$
  31. 22031 A$="":INPUT#1,REC
  32. 22035 LINE INPUT#1,B$:GOSUB 30000
  33. 22036 CLOSE#1
  34. 22037 RETURN
  35. 30000 REM
  36. 30010 REM  break up record into its needed parts
  37. 30020 REM  and damned be he the first to screw up this ordered set!!!
  38. 30030 REM
  39. 30031 REM HINT: a string of 37 commas will clear all fields!
  40. 30040 REM
  41. 30050 R$=B$
  42. 30060 W=1:X=1:Y=1:IF LEN(R$)=0 THEN R$=",,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,"
  43. 30070 FOR I=1 TO 38
  44. 30075 A1$=""
  45. 30080 IF R$="" THEN 30555
  46. 30090 J=INSTR(R$,",")
  47. 30095 IF J<>0 THEN A1$=LEFT$(R$,J-1):R$=MID$(R$,J+1) ELSE IF R$<>"" THEN A1$=R$:R$=""
  48. 30100 REM
  49. 30110 REM
  50. 30120 ON I    GOTO 30170,30180,30190,30200,30210,30210,30210,30210,30250,30250
  51. 30130 ON I-10 GOTO 30250,30250,30250,30300,30310,30320,30330,30340,30350,30360
  52. 30140 ON I-20 GOTO 30370,30380,30390,30350,30360,30370,30380,30390,30350,30360
  53. 30150 ON I-30 GOTO 30370,30380,30390,30350,30360,30370,30380,30390
  54. 30160 STOP
  55. 30170 CNAME$=A1$:GOTO 30550
  56. 30180 HD=VAL(A1$):GOTO 30550
  57. 30190 AG=VAL(A1$):GOTO 30550
  58. 30200 CH=VAL(A1$):GOTO 30550
  59. 30210 SA(X)=VAL(A1$):X=X+1:GOTO 30550
  60. 30250 WA(Y)=VAL(A1$):Y=Y+1:GOTO 30550
  61. 30300 AE=VAL(A1$):GOTO 30550
  62. 30310 SEX$=A1$:GOTO 30550
  63. 30320 GOLD=VAL(A1$):GOTO 30550
  64. 30330 BANK=VAL(A1$):GOTO 30550
  65. 30340 AC=VAL(A1$):GOTO 30550
  66. 30350 WN$(W)=A1$:GOTO 30550
  67. 30360 WT(W)=VAL(A1$):GOTO 30550
  68. 30370 WO(W)=VAL(A1$):GOTO 30550
  69. 30380 WD(W)=VAL(A1$):GOTO 30550
  70. 30390 WS(W)=VAL(A1$):W=W+1:GOTO 30550
  71. 30550 REM
  72. 30555 NEXT I
  73. 30560 RETURN
  74.